Move documents or folders to a child batch

After the Batch_Close event the documents and the subfolders on the first level in the root XFolder are checked for XValues configuring the Document Routing functionality. If XValues with the key KTM_DOCUMENTROUTING exist, their values define string placeholders that represent one ore more child batches. Each unique string placeholder implicitly creates a child batch and the documents or folders that share the same string placeholder as value, are routed to the same child batch. The assignment of the XValues can happen in any appropriate event including the Batch_Close event.

The following keys can be used for moving documents, folders, and for controlling child batch properties:

KTM_DOCUMENTROUTING

The parent object for this key is XDocInfo.

Unique identifier (<PlaceHolder>) of the child batch the document is moved to, this name is not used as name for the batch.

KTM_DOCUMENTROUTING

The parent object for this key is the fist level of XFolder.

Unique identifier (<PlaceHolder>) of the child batch the folder is moved to, this name is not used as name for the batch. These XValues are only recognized for folders on 1st level, all XValues set to dependent objects are ignored if set.

KTM_DOCUMENTROUTING_BATCHNAME_<PlaceHolder>

The parent object for this key is Root XFolder.

Name of the created child batch that is getting visible (optional). If this batch name is already existing it is extended to make it unique (where <PlaceHolder> is the unique identifier of the child batch that is already used for moving documents or folders). If the batch name is not defined a unique name is created automatically.

KTM_DOCUMENTROUTING_NEWBATCHCLASS_<PlaceHolder>

The parent object for this key is Root XFolder.

Name of the batch class the child batch is assigned to (where <PlaceHolder> is the unique identifier of the child batch that is already used for moving documents). Routing folders is not supported when this XValue is present.

The XValue KTM_DOCUMENTROUTING can be attached to documents or to folders on the first level, it is ignored for folders on all deeper levels. If a folder on the first level has this XValue set the folder with its complete sub structure is moved to the defined child batch, routing information for all documents in that moved folder is ignored.

After the Batch_Close event the documents and the subfolders on the first level in the root XFolder are checked for XValues configuring the Batch Routing functionality. If XValues with the key KTM_DOCUMENTROUTING exist, their values define string placeholders that represent one ore more child batches. Each unique string placeholder implicitly creates a child batch and the documents or folders that share the same string placeholder as value, are routed to the same child batch. The assignment of the XValues can happen in any appropriate event including the Batch_Close event.

Defining the Child Batch Name

If you want to set the child batch name explicitly by script, you need to define another XValue with the key KTM_DOCUMENTROUTING_BATCHNAME_<Placeholder> on the root XFolder level with the value that should be used as the name for the child batch. For example, the key KTM_DOCUMENTROUTING_BATCHNAME_BATCH1 ErrorBatch with the value names the created child batch to ErrorBatch. If the given batch name already exists in the Kofax Capture batch list, it is automatically extended to make it unique. If the batch name is not set explicitly, the name of the child batch is created using the name of the parent batch and extending it to make the name unique.

Setting the Batch Class of the Child Batch

By default, a child batch inherits its parent's batch class. If you want the child to have a different batch class, you need to define another XValue with the key KTM_DOCUMENTROUTING_NEWBATCHCLASS_<PlaceHolder> on the root XFolder level with the name of the batch class that should be assigned to the child batch. In case of assigning a new batch class, the assignment of modules to the child batch are ignored. All specific document data are cleared, only OCR related data and custom XValues are kept. Document CSS is only transferred to the new document in the child batch when the property MustSynchronize is set to TRUE.

For more information refer to Accessing Kofax Capture Data - Document Data.

Not existing batch class specified: If the given batch class does not exist, the parent batch is sent to Quality Control.
Routing folders and assigning new batch class: Assigning a new batch class is only supported for routing documents not for routing folders. If folder routing is specified for a child batch for that also a new batch class is specified, Batch Routing is interrupted and the parent batch is send to Quality Control.
Skipped Batch_Close event: For child batches created with a different batch class, no additional Batch_Close event with the CloseMode parameter set to Child is fired. The reason for this is that a different project would have to be loaded to fire this event.

Private Sub Batch_Close(ByVal pXRootFolder As CASCADELib.CscXFolder, ByVal CloseMode As CASCADELib.CscBatchCloseMode)
If CloseMode = CscBatchCloseError Then
      Dim i As Long
      For i = 0 To pXRootFolder.GetTotalDocumentCount - 1
        Dim oXDocInfo As CASCADELib.CscXDocInfo
        Set oXDocInfo = pXRootFolder.GetDocInfoByGlobalIndex(i)
        If Not IsDocumentRejected(oXDocInfo) Then
            oXDocInfo.XValues.Set("KTM_DOCUMENTROUTING", "allokay")
        End If
      Next
      pXRootFolder.XValues.Set("KTM_DOCUMENTROUTING_QUEUE_allokay", "KC.Export")
End If   
End Sub

Private Function IsDocumentRejected(oXDocInfo As CASCADELib.CscXDocInfo) As Boolean
   IsDocumentRejected = False
   If oXDocInfo.XValues.ItemExists("AC_REJECTED_DOCUMENT") Then
      IsDocumentRejected = True
   Else
      Dim nPageIndex As Long
      For nPageIndex = 0 To oXDocInfo.PageCount - 1
         If oXDocInfo.XValues.ItemExists("AC_REJECTED_PAGE" & CStr(nPageIndex + 1)) Then
            IsDocumentRejected = True
         End If
      Next
   End If
End Function

Private Sub Batch_Close(ByVal pXRootFolder As CASCADELib.CscXFolder, ByVal CloseMode As CASCADELib.CscBatchCloseMode)

   If CloseMode < 3 And Project.ScriptExecutionMode = CscScriptModeServer And Project.ScriptExecutionInstance = 1 Then

      Dim i As Long
      For i = 0 To pXRootFolder.GetTotalDocumentCount() - 1
         Dim oXDocInfo As CASCADELib.CscXDocInfo
         Set oXDocInfo = pXRootFolder.GetDocInfoByGlobalIndex(i)
         If Len(oXDocInfo.ExtractionClass) > 0 Then
            ' assign classification result to all documents as routing information
            ' so all documents sharing the same extraction class end up in the same child batch
            oXDocInfo.XValues.Set("KTM_DOCUMENTROUTING", oXDocInfo.ExtractionClass)
         Else
            ' these documents go on processing with the same batch class
            oXDocInfo.XValues.Set("KTM_DOCUMENTROUTING", "Manual")
         End If
      Next

      ' for the extraction classes 'Invoice' and 'Forms' a new batch class is assigned
      ' all other extraction classes are separated into different child batches but they are going on with the same batch class
      pXRootFolder.XValues.Set("KTM_DOCUMENTROUTING_NEWBATCHCLASS_Invoice", "BatchClass_ForInvoices")
      pXRootFolder.XValues.Set("KTM_DOCUMENTROUTING_NEWBATCHCLASS_Forms", "BatchClass_ForForms")

   End If
End Sub

Private Sub Batch_Close(ByVal pXRootFolder As CASCADELib.CscXFolder, ByVal CloseMode As CASCADELib.CscBatchCloseMode)

   If CloseMode < 3 Then ' child and parent batch_close events are ignored

      Dim i As Long
      Dim oXDocInfo As CASCADELib.CscXDocInfo
      If Project.ScriptExecutionMode = CscScriptModeServer Then
         ' all automatically recognized documents are routed to a child batch grouped by extraction class
         For i = 0 To pXRootFolder.GetTotalDocumentCount() - 1
            Set oXDocInfo = pXRootFolder.GetDocInfoByGlobalIndex(i)
            If Len(oXDocInfo.ExtractionClass) > 0 Then
               ' assign classification result to all documents as routing information
               ' so all documents sharing the same extraction class end up in the same child batch
               oXDocInfo.XValues.Set("KTM_DOCUMENTROUTING", oXDocInfo.ExtractionClass)
               ' create an XValue containing specific field data to have it available in the new child batch
               ' this data can be retrieved and reassigned to an XDocument field
               If oXDocInfo.XDocument.Fields.Exists("AccountNumber") Then
                  oXDocInfo.XValues.Set("AccountNumber", oXDocInfo.XDocument.Fields.ItemByName("AccountNumber").Text)
               End If
            Else
               ' these documents go on processing with the same batch class for manual classification
               oXDocInfo.XValues.Set("KTM_DOCUMENTROUTING", "Manual")
            End If
         Next

      ElseIf Project.ScriptExecutionMode = CscScriptModeValidation Then
         ' all documents that are not recognized automatically are now manually processed by validation
         ' and can be routed now
         For i = 0 To pXRootFolder.GetTotalDocumentCount() - 1
            Set oXDocInfo = pXRootFolder.GetDocInfoByGlobalIndex(i)
            If Len(oXDocInfo.ExtractionClass) > 0 Then
               ' assign classification result to all documents as routing information
               ' so all documents sharing the same extraction class end up in the same child batch
               oXDocInfo.XValues.Set("KTM_DOCUMENTROUTING", oXDocInfo.ExtractionClass)
               ' create an XValue containing specific field data to have it available in the new child batch
               If oXDocInfo.XDocument.Fields.Exists("AccountNumber") Then
                  oXDocInfo.XValues.Set("AccountNumber", oXDocInfo.XDocument.Fields.ItemByName("AccountNumber").Text)
               End If
            End If
         Next
      End If

      ' for the extraction classes 'Invoice' and 'Forms' a new batch class is assigned
      ' all other extraction classes are separated into different child batches but they are going on with the same batch class
      pXRootFolder.XValues.Set("KTM_DOCUMENTROUTING_NEWBATCHCLASS_Invoice", "BatchClass_ForInvoices")
      pXRootFolder.XValues.Set("KTM_DOCUMENTROUTING_NEWBATCHCLASS_Forms", "BatchClass_ForForms")

   End If
End Sub

Your search for returned results.

Search tips

Move documents or folders to a child batch

Defining the Child Batch Name

Setting the Batch Class of the Child Batch