Change folder and document field data

The following figure shows the inheritance of folder field data in a simple scenario. The incoming documents are classified and the document type is determined. Depending on the document type a priority is set in script. If a document is reclassified, the priority is adjusted. The maximum of the document's priorities is set as the folder field's maximum priority. The Agent and the Last Change Date are defined on batch level and are thus modified only once, applying to all documents contained in the batch.

The Policy Number is an invisible document field; the initial value is what it was given when the folder was initially created and its value is assigned to a corresponding folder field. Updating this folder field thus affects all documents that are part of the folder.

A visual representation of folder field data inheritance.

Private Sub ValPolicyNumber_ValidateFolderFields(ValItems As CASCADELib.CscXDocValidationItems, _
pXFolder As CASCADELib.CscXFolder, ErrDescription As String, ValidField As Boolean)

   Dim strPolicyNumber As String
   Dim i As Long

   ValidField = True

   For i = 0 To pXFolder.DocInfos.Count - 1
      If i = 0 Then
         strPolicyNumber = pXFolder.DocInfos(i).XDocument.Fields.ItemByName("PolicyNumber").Text
         If pXFolder.Fields.ItemByName("PolicyNumber").Text <> strPolicyNumber Then
             pXFolder.Fields.ItemByName("PolicyNumber").Text = strPolicyNumber
         End If
      Else
         If pXFolder.DocInfos(i).XDocument.Fields.ItemByName("PolicyNumber").Text <> strPolicyNumber Then
            ValidField = False
            ErrDescription = "Folder contains different policy numbers."
            Exit For
         End If
      End If
  Next i

End Sub

Private Sub RootFolder_DoFoldering(pXRootFolder As CASCADELib.CscXFolder)

   Dim i As Long
   Dim oXDoc As CscXDocument

   For i = pXRootFolder.DocInfos.Count - 1 To 0 Step -1
      Dim pFolder As CscXFolder
      Dim sPolicyNumber As String

      Set oXDoc = pXRootFolder.DocInfos(i).XDocument

      ' find existing folder having the PolicyNumber or create a new one
      sPolicyNumber = oXDoc.Fields.ItemByName("PolicyNumber").Text
      Set pFolder = FindFolder(pXRootFolder, sPolicyNumber)

      If pFolder Is Nothing Then

        ' create new folder with document
         Dim nFolderIndex As Long
         nFolderIndex = Batch.CreateFolderFromDocumentTo(pXRootFolder, i, 0)

         Set pFolder = pXRootFolder.Folders(nFolderIndex)
         pFolder.Fields.ItemByName("PolicyNumber").Text = sPolicyNumber
         pFolder.Fields.ItemByName("PolicyNumber").ExtractionConfident = True

      Else

        ' move document into found folder
         Batch.MoveDocumentTo(pXRootFolder, i, pFolder, 0)

      End If

   Next i

End Sub 

Private Function FindFolder(pRootFolder As CscXFolder, sPolicyNumber As String) As CscXFolder

   Dim i As Long

   For i = 0 To pRootFolder.Folders.Count - 1
      If pRootFolder.Folders(i).Fields.ItemByName("PolicyNumber").Text = sPolicyNumber Then
         Set FindFolder = pRootFolder.Folders(i)
         Exit Function
      End If
   Next i

   Set FindFolder = Nothing

End Function

Private Sub Folder_BeforeExtract(pXFolder As CASCADELib.CscXFolder)

   If Project.ScriptExecutionMode = CscScriptModeServerDesign Or Project.ScriptExecutionMode=CscScriptModeServer Then
      pXFolder.Fields.ItemByName("ProcessDate").Text = Format(Now(),"Short Date")
   End If

End Sub

Private Sub Folder_BeforeExtract(pXFolder As CASCADELib.CscXFolder)

   Dim nMaxPriority As Long
   Dim nPriority As Long
   Dim i As Long

   For i = 0 To pXFolder.DocInfos.Count - 1
      nPriority = CInt(pXFolder.DocInfos(i).XDocument.Fields.ItemByName("Priority").Text)
      If nPriority > nMaxPriority Then
         nMaxPriority = nPriority
      End If

   Next i

   pXFolder.Fields.ItemByName("MaxPriority").Text = CStr(nMaxPriority)
   pXFolder.Fields.ItemByName("MaxPriority").ExtractionConfident = True

End Sub

Private Sub Document_AfterExtract(pXDoc As CASCADELib.CscXDocument)

   Select Case pXDoc.Fields.ItemByName("DocType").Text
      Case "Address Change"
         pXDoc.Fields.ItemByName("Priority").Text = "1"
      Case "Payment Reminder"
         pXDoc.Fields.ItemByName("Priority").Text = "10"
      Case "Banking Account Change"
         pXDoc.Fields.ItemByName("Priority").Text = "5"
   End Select

   pXDoc.Fields.ItemByName("Priority").ExtractionConfident = True

End Sub

Private Sub ValidationForm_AfterComboboxItemSelected(ByVal ComboboxName As String, _
pXDoc As CASCADELib.CscXDocument, ByVal SelectedIndex As Long, ByVal SelectedText As String)

   Select Case ComboboxName
      Case "DocType"
         Select Case SelectedText
            Case "Address Change"
               pXDoc.Fields.ItemByName("Priority").Text = "1"
            Case "Payment Reminder"
               pXDoc.Fields.ItemByName("Priority").Text = "10"
            Case "Banking Account Change"
               pXDoc.Fields.ItemByName("Priority").Text = "5"
         End Select
   End Select

End Sub

Private Sub ValidationForm_BeforeComboBoxDropDown(ByVal ComboboxName As String, pXDoc As CASCADELib.CscXDocument, ComboboxItems As String)

   Select Case ComboboxName
      Case "DocType"
          ComboboxItems = "Payment Reminder;Banking Account Change;Address Change"
   End Select

End Sub

Your search for returned results.

Search tips

Change folder and document field data