The following is available for document data:

Document Index Fields (mapped)

For all mapped document index fields you have read/write access. By updating the document field of the XDocInfo.XDocument object its data is written to the mapped Kofax Capture document index field. Initial field values from Kofax Capture document index fields are not considered.

Mapped table fields have read/write access and by updating the table of the XDocInfo.XDocument object its data are written to the mapped Kofax Capture table field.

Note The "Populate all fields for read-only access" option is not required for mapped index fields.

Document Index Field Values

During runtime all document index field values (mapped and unmapped) are accessible read-only from script. They are saved as XValues of the XDocInfo object.

XDocInfo.XValues.ItemByName("AC_FIELD_" & FieldName)

Note If you cannot access the field values via script, then you need to check whether the "Populate all index fields for read-only access in script" option is selected on the Extended Synchronization Settings window of the Kofax Transformation - Synchronization Tool. This option is cleared by default.

Note Default values defined in Kofax Capture for document index fields are filled for the Kofax Capture validation step. The corresponding XValues remain empty during server processing. If you want to access the value you have to add Kofax Capture Validation module in the processing queue before Kofax Transformation - Validation.

Table Field Values

During runtime all table fields values are accessible read-only from script. They are saved row by row in the XValues of the XDocInfo object. The row number is zero-based and the columns are separated by [Tab]. See below a script example.

XDocInfo.XValues.ItemByName("AC_TABLE_" & TableFieldName & "_ROW_" & nRowNumber)

Form Type

The Kofax Capture form type name can be accessed read-only using the following key:

XDocInfo.XValues.ItemByName("AC_FORMTYPE")

Document CSS

Additionally, all custom storage strings defined on document level on the Kofax Capture side are transferred to the XValues collection of the XDocInfo object.

XDocInfo.XValues.ItemByName("AC_CSS_" & CSSName)

In order to write values back to Kofax Capture, set the property MustSynchronize to TRUE so that changes in the XValue are transferred to the corresponding document's CustomStorageString. By using the naming convention and setting the property MustSynchronize to TRUE you can also add new XValues to the collection of the XDocInfo so that new CustomStorageStrings on Kofax Capture side are created.

Page CSS

All custom storage strings defined on page level on the Kofax Capture side are transferred to the XValues collection of the XDocInfo object.

XDocInfo.XValues.ItemByName("AC_CSS_PAGE<n>_" & CSSName)

In order to write values back to Kofax Capture, set the property MustSynchronize to TRUE so that changes in the XValue are transferred to the corresponding page's custom storage string, where <n> is the one-based page number of the page you are interested in. By using the naming convention and setting the property MustSynchronize to TRUE you can also add new XValues to the collection of the XDocInfo so that new custom storage strings on Kofax Capture side are created.

Document or Page(s) Rejected

If a document or one of its pages is rejected in Kofax Capture is reflected in the XValues of the document.

The following XValue keys are reflecting the rejection state of documents and pages:

XDocInfo.XValues.ItemByName("AC_REJECTED_DOCUMENT")

By using the following key you get the XValue that contains the rejection note for a rejected document:

XDocInfo.XValues.ItemByName("AC_REJECTED_DOCUMENT_NOTE").

If a document has one or more rejected pages, you find an XValue per rejected page in the document with the following key:

XDocInfo.XValues.ItemByName("AC_REJECTED_PAGE<n>")

Where <n> is the one-based page number of the page you are interested in. To get the rejection note of a page get the value of the XValue by the following key:

XDocInfo.XValues.ItemByName("AC_REJECTED_PAGE_NOTE<n>")

Also setting the rejection state of a document or page and modifying its rejection note is supported. All modifications are updated on the side of Kofax Capture when the batch is closed.

Unique ID

This XValue is available only when the Expose document UniqueID in script option is enabled in the Synchronization Tool. Since this option can slow down performance, enable the Expose document UniqueID in script option if this XValue is required. For more information about the Expose document UniqueID in script option, see the Synchronization Tool Help.

The Kofax Capture Unique ID name is read-only and can be accessed using the following key:

XDocInfo.XValues.ItemByName("AC_UNIQUEID")

Important This key is not available for newly created documents in the Thin Client modules and when creating documents using batch restructuring.

Private Sub Document_BeforeExtract(pXDoc As CASCADELib.CscXDocument)
  Dim sRow As String
  Dim n As Long
  Dim sCols() As String

  ' first row index is zero
  n = 0

  While pXDoc.XValues.ItemExists("AC_TABLE_MyTableName_Row_" & n) = True

      sRow = pXDoc.XValues.ItemByName("AC_TABLE_MyTableName_Row_" & n).Value
      sCols = Split(sRow, vbTab)

      ' ...
      ' use the column results for your needs
      ' ...

      n = n + 1

  Wend

End Sub

Private Function IsDocumentRejected(oXDocInfo As CASCADELib.CscXDocInfo) As Boolean
   IsDocumentRejected = False
   If oXDocInfo.XValues.ItemExists("AC_REJECTED_DOCUMENT") Then
      IsDocumentRejected = True
   Else
      Dim nPageIndex As Long
      For nPageIndex = 0 To oXDocInfo.PageCount - 1
         If oXDocInfo.XValues.ItemExists("AC_REJECTED_PAGE" & CStr(nPageIndex + 1)) Then
            IsDocumentRejected = True
         End If
      Next
   End If

End Function

Private Function GetRejectionNote(oXDocInfo As CASCADELib.CscXDocInfo, Optional nPageIndex = 0 As Long) As String

   GetRejectionNote = ""

   If nPageIndex = 0 Then
      ' get the rejection note of the document
      If oXDocInfo.XValues.ItemExists("AC_REJECTED_DOCUMENT_NOTE") Then
         GetRejectionNote = oXDocInfo.XValues.ItemByName("AC_REJECTED_DOCUMENT_NOTE")
      End If
   Else
      ' get the rejection note of the page, nPageIndex is one-based
      If oXDocInfo.XValues.ItemExists("AC_REJECTED_PAGE_NOTE" & CStr(nPageIndex)) Then
         GetRejectionNote = oXDocInfo.XValues.ItemByName("AC_REJECTED_PAGE_NOTE" & CStr(nPageIndex))
      End If
   End If

End Function