Folders

The foldering can be used to group documents based on specific information and summarize document data at different levels.

The general description of foldering is done in the chapter about the RootFolder object that is handling the events for the foldering implementation.

It allows you to bracket documents which are logically belonging together, like documents send by one customer. The folder fields can be used to summarize document data like invoice totals to have an overview about the total of a batch of if the documents are grouped by supplier the total of the invoices per supplier.

The methods provided by the scripting interface of the Batch object (Batch Restructuring) can be used to move documents and create folders.

In two sample projects installed with Project Builder the following scenarios are presented:

Creates a folder for all documents with the same value in the field DepotNumber and moves the documents to it.

' RootFolder Script
Private Sub RootFolder_DoFoldering(pXRootFolder As CASCADELib.CscXFolder)

   If Project.ScriptExecutionMode = CscScriptModeValidation Then Exit Sub

   Dim i As Long

   For i = pXRootFolder.DocInfos.Count - 1 To 0 Step -1

      Dim pFolder As CscXFolder 
      Dim DepotNumber As String

      If pXRootFolder.DocInfos(i).XDocument.Fields.Exists("DepotNumber") Then 
         DepotNumber = pXRootFolder.DocInfos(i).XDocument.Fields.ItemByName("DepotNumber").Text 
      Else 
         DepotNumber = "" 
      End If

      Set pFolder = FindFolder(pXRootFolder, DepotNumber)

      If pFolder Is Nothing Then

         Dim nFolderIndex As Long
         nFolderIndex = Batch.CreateFolderFromDocumentTo(pXRootFolder, i, 0)
         Set pFolder = pXRootFolder.Folders(nFolderIndex) 
         pFolder.Fields.ItemByName("DepotNumber").Text = DepotNumber

      Else

         Batch.MoveDocumentTo(pXRootFolder, i, pFolder, 0)

      End If

   Next i

End Sub

Private Function FindFolder(pRootFolder As CscXFolder, Depotnummer As String) As CscXFolder

   Dim i As Long

   For i = 0 To pRootFolder.Folders.Count - 1
      If pRootFolder.Folders(i).Fields.ItemByName("Depotnummer").Text = Depotnummer Then
         Set FindFolder = pRootFolder.Folders(i)
         Exit Function
      End If
   Next i

   Set FindFolder = Nothing

End Function

Creates a sub folder for each document and moves the document to it.

' RootFolder Script
Private Sub RootFolder_DoFoldering(pXRootFolder As CASCADELib.CscXFolder) 

   If Project.ScriptExecutionMode = CscScriptModeValidation Then Exit Sub

   ' removing documents from the head of the list 
   While pXRootFolder.DocInfos.Count > 0

      ' create new sub folder for each document
      Batch.CreateFolderFromDocument(pXRootFolder, 0) 

   Wend

End Sub

Your search for returned results.

Search tips

Folders